创建 PDF

在内存中创建一个空的 PDF 文件。使用“附加 PDF”等脚本步骤添加页面，然后使用“关闭 PDF”脚本步骤关闭并保存文件。

另请参阅 

选项 

  • “指定选项”显示“PDF 选项”对话框。选择此选项时，“恢复”表示 PDF 选项存储在脚本步骤中。

    • 在“文档”选项卡中，可以为 PDF 文件指定描述性信息。对于“文档”选项卡中的每个选项，可以直接输入文本，也可以单击“指定”以通过算式输入字段名称或值。

    • 在“安全性”选项卡中，可以为 PDF 文件指定密码，还可以指定打印和编辑权限。如果允许打印和编辑权限，则可以指定是否允许拷贝和屏幕阅读软件。

    • 在“初始视图”选项卡中，可以定义布局的初始视图，还可以定义 PDF 文件的放大倍率。

兼容性 

产品 是否支持
FileMaker Pro 是
FileMaker Go 是
FileMaker WebDirect 是
FileMaker Server 是
FileMaker Cloud 是
FileMaker Data API 是
自定义 Web 发布 是

原始版本 

26.0

说明 

此脚本步骤在内存中创建一个新的空白 PDF 文件，然后您可以使用其他 PDF 文件脚本步骤对其进行修改。PDF 文件已打开，并保持打开状态，直到您使用关闭 PDF脚本步骤或取消 PDF脚本步骤关闭它。

打开 PDF 文件后，您可以：

此工作流程可用于创建复杂的 PDF 文档，这些文档将来自多个来源的页面（如封面、报告数据和附录）组合在一起，全部汇编成一个 PDF 文件。

注释 

  • 一次只能打开一个 PDF 文件。如果 PDF 文件已打开，此脚本步骤将返回错误代码 833 (“PDF 文件已打开”)。

  • 创建的 PDF 文件仅存在于内存中，直到您使用关闭 PDF脚本步骤将其保存。

  • 如果发生以下任一情况，打开的 PDF 文件和任何未保存的更改都将丢失：

    • 当前的 FileMaker 客户端会话结束

    • 其脚本打开了 PDF 文件的 FileMaker Pro 文件关闭而未关闭打开的 PDF 文件

示例 1 - 创建一个简单的 PDF 文档

创建 PDF 文件，为当前正在浏览的记录添加页面，并将其保存到“文档”文件夹中。

复制 
创建 PDF [ ]

转到布局 [ "联系人" (联系人) ; 动画: 无 ]

将记录另存为 PDF [ 恢复 ; 保存到: 当前打开的 PDF ; 正在浏览的记录 ]

设置变量 [ $pdfFilePath ; 值: Get ( 文档路径 ) & "Report.pdf" ]

关闭 PDF [ 保存到: 文件 ; $pdfFilePath ; 创建文件夹: 关闭 ]

示例 2 - 创建多部分 PDF 报告

通过合并封面、多个数据部分和摘要页面来创建加密的 PDF 报告。创建 PDF 使用“指定选项”设置用于打开文件的密码。

复制 
创建 PDF [ 恢复 ]

附加 PDF [ 来自: 文件 ; "CoverPage.pdf" ]

转到布局 [ "订单" (订单) ]
记录另存为 PDF [ 恢复 ; 保存到: 当前打开的 PDF ; 正在浏览记录 ]

转到布局 [ "客户" (客户) ]
记录另存为 PDF [ 恢复 ; 保存到: 当前打开的 PDF ; 正在浏览记录 ]

附加 PDF [ 来自: 源 ; Global::SummaryPage ]

设置变量 [ $pdfFilePath ; 值: Get ( 文档路径 ) & "Complete_Report_" & Year ( Get ( 当前日期 ) ) & ".pdf" ]

关闭 PDF [ 保存到: 文件 ; $pdfFilePath ; 创建文件夹: 关闭 ]

示例 3 - 创建带有错误处理的 PDF

创建带有错误处理的 PDF 报告，以确保在出现错误时关闭 PDF 文件。请注意，在尝试修改 PDF 文件失败后，通过取消 PDF脚本步骤关闭 PDF 文件而不保存。

复制 
设置错误捕获 [ 打开 ]

创建 PDF [ ]
设置变量 [ $errorCode ; 值: Get ( 上一个错误 ) ]
If [ $errorCode ≠ 0 ]
    显示自定义对话框 [ "错误" ; "无法创建 PDF: " & $errorCode ]
    退出脚本 [ 文本结果: "失败" ]
End If

附加 PDF [ 从: 文件 ; "CoverPage.pdf ]
设置变量 [ $errorCode ; 值: Get ( 上一个错误 ) ]
If [ $errorCode ≠ 0 ]
    取消 PDF
    显示自定义对话框 [ "错误" ; "无法添加封面: " & $errorCode ]
    退出脚本 [ 文本结果: "失败" ]
End If

记录另存为 PDF [ 恢复 ; 保存到: 当前打开的 PDF ; 正在浏览记录 ]
设置变量 [ $errorCode ; 值: Get(上一个错误) ]
If [ $errorCode ≠ 0 ]
    取消 PDF
    显示自定义对话框 [ "错误" ; "无法添加记录: " & $errorCode ]
    退出脚本 [ 文本结果: "失败" ]
End If

关闭 PDF [ 保存到: 文件 ; "Report.pdf" ; 创建文件夹: 关闭 ]
设置变量 [ $errorCode ; 值: Get ( 上一个错误 ) ]
If [ $errorCode = 0 ]
    显示自定义对话框 [ "成功" ; "PDF 已成功创建" ]
Else
    显示自定义对话框 [ "错误" ; "无法保存 PDF: " & $errorCode ]
End If

相关主题