Definir campo por nome

Substitui todo o conteúdo de um campo de destino calculado no registro atual pelo valor calculado.

Opções 

• Especificar campo de destino é um cálculo para especificar o campo cujo conteúdo você deseja substituir.
• Resultado calculado especifica o cálculo cujos resultados serão inseridos por esta etapa de script.

Originada na versão 

10.0

Descrição 

A etapa de script Definir campo por nome permite que você crie um cálculo para especificar um nome de campo e, em seguida, altere o valor do campo literalmente ou com base em um segundo cálculo.

Como o campo de destino é calculado, um etapa única Definir campo por nome pode substituir várias Etapa de script Definir campo entre condições If.

O campo de destino calculado deve retornar um resultado de texto.

Se o nome do campo totalmente qualificado não for colocado entre aspas, o nome do campo de destino será obtido a partir do campo nomeado.

Se não houver campo especificado e um campo for selecionado no Modo de navegação ou no Modo de busca, esse campo será usado.

Notas 

• O campo de destino especificado não precisa estar no layout atual.
• Definir campo por nome ignora a verificação de validação.
• Quando possível, a etapa de script Definir campo por nome tornará o registro ativo e o manterá assim até que o registro seja fechado ou confirmado. Os scripts que usam uma série de etapas de script Definir campo por nome devem agrupá-las se possível, para que as etapas de script Definir campo por nome subsequentes possam atuar no registro sem precisar bloqueá-lo, baixar e carregar dados, indexar o campo etc., após cada etapa. Essas funções e a validação no nível do registro são executadas após o fechamento ou a confirmação do registro.

Exemplo 1 

Identifica o campo de destino (Estatísticas nacionais ou Estatísticas mundiais) com base na localização geográfica e insere um valor calculado (a soma de todos os Totais gerais) no campo de destino.

Definir campo por nome [If ( Clientes::País = "Japão" ; "Clientes::Estatísticas nacionais" ; "Clientes::Estatísticas mundiais" ); Soma ( Faturas::Total geral )]

Exemplo 2 

Mostra quando usar Definir campo por nome, em vez de Definir campo, para simplificar scripts.

#Com Definir campo, uma instrução If com várias etapas Else If é necessária
#para determinar qual campo na tabela Clientes deve ser atualizado
#com as informações de Cobrança de crédito::Número de telefone.

If [Cobrança de crédito::Local da chamada = "Trabalho"]
    Definir campo [Clientes::Telefone comercial; Cobrança de crédito::Número de telefone]
Else If [Cobrança de crédito::Local da chamada = "Residencial"]
    Definir campo [Clientes::Telefone residencial; Cobrança de crédito::Número de telefone]
Else If [Cobrança de crédito::Local da chamada = "Celular"]
    Definir campo [Clientes::Telefone celular; Cobrança de crédito::Número de telefone]
End If

#Uma única etapa de script Definir campo por nome pode executar a mesma tarefa
#usando um cálculo para determinar o campo de destino.

Definir campo por nome [GetFieldName ( Avaliar ( Cobrança de crédito::Local da chamada & " Telefone" ) ); Cobrança de crédito::Número de telefone]

Tópicos relacionados 

• Referência de etapas de script